6 de jul. de 2012

Tratamento de exceção é uma prática de programação de antecipar possíveis erros que um programa pode encontrar durante sua execução. No VBA, sabemos que não podemos dividir um número por 0 que obtemos um erro. Se você tiver, por exemplo, a rotina:


Sub Erro()

Dim sng As Single
   
    sng = 1 / 0
   
End Sub


Ao tentar executar o código, a seguinte janela será apresentada:




Houve um erro em tempo de execução. O erro é em temo de execução porque ocorreu após o VBA ter compilado o código e o mesmo estar em execução. Este artigo mostra como alterar o comportamento do VBA quando deparado com um erro em tempo de execução, usando a instrução On Error.

Enquanto se está escrevendo um sistema ou programando, é desejável visualizar os erros a fim de corrigi-los. No entanto, quando se trata de um projeto acabado para um cliente, é inaceitável esse tipo de ocorrência.

A seguir algumas técnicas de tratamento de exceção.

On Error Resume Next

A instrução On Error Resume Next é a forma mais usada de tratamento de exceção. Observe o código abaixo, similar ao daIntrodução:


Sub ResumeNext()
      Dim sng As Single
       On Error Resume Next
       sng = 1 / 0
End Sub

Essa instrução simplesmente ignora os erros em tempo de execução e procede o código na próxima linha. Traduzindo ao pé da letra,On Error Resume Next seria algo como "ao encontrar um erro, prosseguir o código a partir da próxima linha".

Um exemplo de como essa instrução pode ser usada segue abaixo:

Sub ResumeNext2()

    Dim wb As Workbook
   
    On Error Resume Next
    Set wb = Workbooks.Open("c:\teste\teste.xlsx")
   
    If Err.Number > 0 Then
        MsgBox "A Pasta de Trabalho 'teste' não encontrada!" _
          , vbCritical _
          , "Erro!"
        Exit Sub
    End If
   
    wb.Sheets(1).Range("A1") = "Olá!"
   
End Sub


Suponha que não exista um arquivo no caminho mencionado acima (c:\teste\teste.xlsx). O VBA acusaria um erro em tempo de execução, mas como antes de tentar abrir a Pasta de Trabalho há a instrução On Error Resume Next, o erro será ignorado. Em seguida, há um teste condicional para verificar se Err.Number é maior que 0.

Err.Number é um valor que assume o valor maior que 0 caso um erro seja encontrado em tempo de execução. Dependendo da natureza do erro, esse valor é diferente. Há uma tabela nesse link que mostra todos os erros possíveis de serem tratados com a instrução On Error:

http://support.microsoft.com/kb/146864. No entanto, a forma que faço para identificar o valor de um erro é forçá-lo no meu código e, em modo de depuração, escrever o comando Debug.Print Err.Number, para visualizá-lo na Janela de Verificação Imediata.

Se seu valor for 0, significa que não houve erro (traduzindo isso para o exemplo acima, significaria que a Pasta de Trabalho indicada abriu com sucesso).

O teste condicional, ao verificar que Err.Number é maior que 0, mostra uma Caixa de Mensagem e em seguida sai da rotina.

Use essa instrução com cuidado. Algumas pessoas têm o hábito de usar essa instrução durante todo o código para que o mesmo não seja interrompido pela Caixa de Diálogo padrão de erro do VBA. No entanto, lembre-se: On Error Resume Next evita os erros, mas não os corrige.

On Error GoTo (rótulo)

Observe o código abaixo:

Sub Tratamento()

    On Error GoTo ErroTratamento
    Sheets("Plan99").Activate
   
    MsgBox "A Planilha 'Plan99' está ativa!" _
      , vbInformation _
      , "Informação"
   
    Exit Sub

ErroTratamento:
    If Err.Number = 9 Then
        'Código 9: significa que Planilha não existe.
        'Deveremos criá-la.
        Sheets.Add.Name = "Plan99"
        Resume
   
    End If
End Sub


A linha On Error GoTo ErroTratamento significa que se um erro for encontrado em tempo de execução, o código saltará para o rótuloErroTratamento.

O erro de valor 9 corresponde que um objeto não foi encontrado. O objeto, neste caso, é a planilha de nome Plan99. Quando o teste condicional verifica que o erro é de valor 9, toma uma medida para corrigir a situação, criando a Planilha que originou o erro, e em seguida há a instrução Resume, que pode estar em três formas:

-Resume é uma instrução que retorna para a mesma linha em que houve o erro, neste caso Sheets("Plan99").Activate.

-Resume Next é uma instrução que retorna para a próxima linha em que houve o erro, neste a instrução MsgBox.

-Resume (rótulo) é uma instrução que retorna para um rótulo específico, exemplificado ao fim desta seção.

Veja um exemplo com a instrução Resume Next:


Sub Tratamento2()

    Dim sng As Single
    On Error GoTo ErroTratamento2:
   
    sng = 1 / 0
   
    MsgBox "O valor de sng é " & sng _
      , vbInformation _
      , "Informação"

Exit Sub

ErroTratamento2:
    sng = 1
    Resume Next

Veja um exemplo com a instrução Resume (rótulo):

Sub ExemploResumeRótulo()

    On Error GoTo TratamentoRótulo
    Dim n As Long
    n = 1 / 0
    'código que pula se erro acontecer
Rótulo1:
    'algum código
  
    Exit Sub

TratamentoRótulo:
    '
    'Algum tratamento
    '
    'Retorna ao Rótulo1
    Resume Rótulo1
End Sub

Diferentes Procedimentos

Veja o código abaixo:

Sub Proc1()
   
    On Error GoTo TProc1
   
    '1 - Chama Proc2
    Debug.Print Proc2(50)

Exit Sub

TProc1:
    '7 - Vem-se a linha abaixo porque Proc2 não possui
    'tratamento de exceção.
    MsgBox "Houve erro nesta rotina ao se tentar calcula Proc2(50)!" _
      , vbCritical _
      , "Erro!"
End Sub

Function Proc2(ByVal a As Long) As Long

    '2 - Chama Proc3
    Proc2 = (a * 10) / Proc3(a)

    '6 - A linha abaixo gera um erro. Este procedimento não
    'possui tratamento de exceção, então voltar-se-á ao
    'procedimento que o chamou.
    Proc2 = (Proc2 ^ 2) / ((Proc2) - 10)

End Function


Function Proc3(ByVal b As Long) As Long

    On Error GoTo TProc3
   
    '3 - Gera Erro de divisão por 0 e vai no rótulo TProc3
    Proc3 = b / (b - 50)

    '5 - Retorna para Proc2
    Exit Function

TProc3:
    '4 - Resolve problema e volta para mesma linha onde houve o erro
    b = b + 1
    Resume
End Function


Se depurado (tecla F8), o código ocorre na sequência numerada dos comentários.

Proc1 é um procedimento que chama a Função Proc2, que por sua vez, chama a Função Proc3. Um erro ocorre em Proc3, mas pelo fato da mesma possuir tratamento de exceção, trata-se o erro na própria função. Ao retornar à Proc2, ocorre um erro novamente. Como Proc2 não possui tratamento de exceção, sai-se da função, retornando a quem a chamou. Se essa rotina pai possui tratamento, trata-se o erro nela. No nosso caso, essa rotina pai é o Procedimento Proc1, e o mesmo possui tratamento de exceção, que é a próxima linha de código executado.

Em resumo, quando há um erro numa rotina que foi chamada por outra, verifica-se se há tratamento na rotina em que o erro foi gerado. Caso não haja, volta-se a quem a chamou. Se ela possui tratamento, trata-se o erro, caso contrário, sobe-se mais um nível, e assim por diante.

Caso subam-se todos os níveis sem o erro ser tratado, mostra-se a janela de erro padrão mostrada na Introdução.

Mesmo Procedimento

É possível tratar um erro dentro de um tratamento de erro, como mostra o código abaixo:

Sub MesmoProcedimento()

    Dim a As Single
    Dim b As Single
   
    On Error GoTo Trata1
   
    a = 1
    b = 0
    'Erro é gerado
    Debug.Print a / b
Exit Sub

Trata1:
    On Error GoTo Trata2
    'a = 1, então há divisão por 0
    b = (b + 1) / (1 - a)
Resume
Trata2:
    a = a + 1
Resume
End Sub

On Error GoTo 0

Diferentemente do que vimos na seção anterior, a Instrução On Error GoTo 0 não vai para a linha 0 caso haja algum erro. Unicamente quando se usa o 0, o VBA interpreta que erros não são mais tratados, ou seja, volta-se à condição de interrupção do VBA caso haja um erro, mostrado na


Você pode misturar várias instruções On Error numa mesma rotina.

Suponha que não exista a Planilha Plan100 e seja executada a rotina abaixo:

Sub ExemploGoTo0()
   
    On Error Resume Next
   
    'A rotina prosseguirá na linha seguinte à de baixo,
    'ignorando o erro que ocorrerá na linha abaixo:
    Sheets("Plan100").Activate
   
    'A instrução abaixo retorna a interrupção ao padrão do VBA,
    'isto é, em caso de erro, mostra-se a janela padrão de exceção
    'em tempo de execução
    On Error GoTo 0
   
    'A linha abaixo ocasiona um erro e a janela de erro padrão aparecerá
    Sheets("Plan100").Activate
   
End Sub

A explicação da rotina já está no próprio código.

Atenção: Essa instrução limpa o valor de Err.Number. Suponha que houve um tratamento de exceção, e Err.Number, portanto, é 0. Caso essa instrução seja executada, o valor de Err.Number é zerado. Você pode limpar o valor de Err.Number também usando a instrução Err.Clear.

Código Padrão para Tratamento de Exceção

Veja a estrutura do código que uso normalmente para tratar exceções num projeto:

Sub CódigoPadrão()
    Const sRotina = "CódigoPadrão"
    On Error GoTo Erro
     Dim l As Long
    l = 1 / 0
    '
    'código que pula se erro acontecer
Fim:
     'código de finalização, limpeza de memória, etc.
     Exit Sub

Erro:
    MsgBox "Erro " & Err.Number & " na rotina '" & sRotina & "'." & vbCrLf & _
      "Descrição do erro: " & Err.Description, vbCritical, "Erro!"
    GoTo Fim
End Sub

Observe as partes em negrito do código. A definição da constante indica qual é a rotina em execução e a mensagem do erro mostra o número e a descrição do erro. No caso dessa rotina, veja o resultado:






0 comentários:

Postar um comentário