6 de jul. de 2012

Introdução
confira a referência abaixo

Considere o código abaixo:


Sub ExemploInterromper()
    
    Dim sng As Single
    
    sng = Timer
    Do While sng + 5 > Timer
        'Só é possível sair deste laço após 5 segundos
    Loop

End Sub





Esse simples exemplo é uma rotina que entra num laço e só sai do mesmo após 5 segundos. Caso o usuário, nesses 5 segundos, pressione a combinação Ctrl+Break, a seguinte tela será mostrada:





O código é interrompido imediatamente, e então é mostrada uma janela em que o usuário tem as opçoes de continuar a executar a rotina, finalizar a execução ou depurar (o VBE mostra a última linha que foi executada antes da interrupção).

No entanto, dependendo de alguns sistemas implementados em VBA, interromper abrutamente um código pode comprometer o funcionamento de do mesmo porque é na finalização de uma rotina que algumas vezes existe espaço para esvaziar memória, apagar arquivos temporários, limpar variáveis com memória, etc.


Este artigo discute formas alternativas de comportamento do VBA para o uso da tecla Ctrl+Break.


Propriedade Application.EnableCancelKey


Nos exemplos abaixo, o que irá alterar o comportamento das teclas de interrupção do código é a Propriedade EnableCancelKey do Objeto Application. Numa rotina, ao escrever Application.EnableCancelKey =, veja com o que irá se deparar:





O Intellisense mostra que é possível atribuir três valores enumerados à EnableCancelKey, que são xlDisabled, xlErrorHandler exlInterrupt.

O valor padrão é xlInterrupt. Quando a propriedade está atribuída à esse valor, o comportamento do VBE ao se pressionar Ctrl+Breakem execução é o descrito acima (Caixa de Mensagem A execução do código foi interrompida).

Se você desejar usar um valor diferente de xlInterrupt para essa propriedade, você sempre deverá explicitar em sua rotina, porque seu valor é resetado para xlInterrupt toda vez que se inicia a execução de um código em sua Aplicação.

Você pode alterar quantas vezes quiser numa rotina o valor dessa Propriedade. Se quiser que no início seja xlDisabled e depoisxlErrorHandler, por exemplo, pode fazê-lo à vontade.

Abaixo seguem exemplos para quando esse valor é xlErrorHandler ou xlInterrupt.


Desativar Funcionalidade da Combinação Ctrl+Break

Observe o código abaixo:


Sub DesativarInterromper()
    
    Dim sng As Single
    
    Application.EnableCancelKey = xlDisabled
    
    sng = Timer
    Do While sng + 5 > Timer
        'Só é possível sair deste laço após 5 segundos
    Loop

End Sub





Diferentemente do exemplo , o VBE irá ignorar a combinação Ctrl+Break e o código executará até o fim. Não recomendo o uso dessa prática a não ser em fragmentos de código críticos que, se não executados, podem comprometer a funcionalidade de um sistema.

O lado negativo é que, se seu programa entrar num laço infinito, você só poderá finalizá-lo com o uso do Ctrl+Alt+Del (Gerenciador de Tarefas) e finalizar o processo. Com isso, você perde todas as alterações feitas em todos os documentos abertos por sua Aplicação.

Um outro contra é a insatisfação de um usuário que, ao pressionar Ctrl+Break, perceber que nada está acontecendo. Ele quer depurar o código, mas não consegue.

Uma alternativa mais interessante vem a seguir.

Gerenciar Interrupção de Código

Veja o código:


Sub GerenciarInterromper()
    
    On Error GoTo Erro
    
    Dim sng As Single
    
    Application.EnableCancelKey = xlErrorHandler
    
    sng = Timer
    Do While sng + 5 > Timer
        'Só é possível sair deste laço após 5 segundos
    Loop
    
    Exit Sub
    
Erro:
    If Err.Number = 18 Then
        MsgBox "Aguarde, Não ha problemas no código..." _
          , vbCritical _
          , "Atenção!"
        Resume
    End If
End Sub





Esse exemplo necessita conhecimento básico de rotinas de tratamento de erro. Pretendo escrever sobre o assunto em breve.

Quando o valor da Propriedade EnableCancelKey for xlErrorHandler, ao pressionar a combinação Ctrl+Break, o VBA levantará um erro cujo código é número 18. A rotina de tratamento do erro mostra uma mensagem ao usuário caso o mesmo pressione a combinação de teclas de interrupção quando o código estiver no meio do laço:







0 comentários:

Postar um comentário